Menjalankan linux virtual menggunakan qemu di windows

Inilah cara saya menjalankan versi minimal CentOS 7 di Windows 7 Enterprise, 64 bit, tanpa menjadi anggota grup administrator (non-admin).

Ide dasarnya adalah:

1. Unduh qemu untuk windows dan unzip di mana saja
2. Unduh image ISO dari distribusi Linux yang ingin Anda jalankan
3. Buat file yang akan menjadi hard disk mesin virtual Anda
4. Jalankan qemu, booting dari citra CD
5. Instal OS
6. Boot ulang mesin virtual, kali ini tanpa gambar CD

Jaringan dan grafik mewah sulit untuk dilakukan dengan benar. Masih berjuang, sebenarnya...

1. Unduh QEMU

Gunakan biner yang telah dikompilasi yang ditemukan di halaman tautan QEMU. Saya menggunakan versi 2.8.0 untuk ini.

Untuk "menginstal" versi ini sebagai non-admin, buka prompt perintah, keluarkan perintah set __COMPAT_LAYER=RunAsInvoker dan jalankan qemu-w64-setup-20170131.exe dari prompt itu. Instal di folder tempat Anda memiliki izin menulis, seperti "Dokumen Saya" atau semacamnya.

2. Unduh citra ISO Linux

Sekali lagi, bantu dirimu sendiri. Saya menggunakan distribusi Minimal CentOS 7, file tersebut bernama CentOS-7-x86_64-Minimal-1611.iso .

3. Buat hard disk virtual

Saya menggunakan file batch untuk ini. Salin yang berikut ke file bernama createvm.bat dan sesuaikan variabel agar sesuai dengan lingkungan Anda:

@echo off
rem ==================================
rem Replace with your values
rem ==================================
set "QEMUDIR=%USERPROFILE%\Documents\Warez\qemu-2.8.0-win64"

rem ==================================
rem Safety net
rem ==================================
if not exist hda.img (
    rem CREATE a virtual hard disk 
    %QEMUDIR%\qemu-img.exe create hda.img 40G
) else (
    echo file hda.img already exist. Delete or move and try again.
    goto:eof
)

4. Jalankan QEMU, booting dari CD virtual

Gunakan batch untuk yang satu ini, karena Anda mungkin sering menggunakannya. Salin yang berikut ke installvm.bat :

@echo off

rem ==================================
rem Replace with your values
rem ==================================
set "QEMUDIR=%USERPROFILE%\Documents\Warez\qemu-2.8.0-win64"
set "ISOFILE=CentOS-7-x86_64-Minimal-1611.iso"

rem ==================================
rem You can add a w suffix to this if 
rem you don't want a console
rem ==================================
set "QEMUBIN=qemu-system-x86_64.exe"

rem ==================================
rem Run the virtual machine
rem ==================================
start "QEMU" %QEMUDIR%\%QEMUBIN% -drive file=hda.img,index=0,media=disk,format=raw -cdrom %ISOFILE% -m 2G -L Bios -usbdevice mouse -usbdevice keyboard -boot menu=on -rtc base=localtime,clock=host -parallel none -serial none -name centos -no-acpi -no-hpet -no-reboot 

5. Instal OS

Saya mengalami masalah dengan penginstal GUI. Saat diminta untuk menginstal CentOS, tekan TAB kunci dan ganti kata quiet di akhir baris itu dengan kata text .

Ikuti petunjuk instalasi di layar. Saat instalasi selesai, mesin virtual akan keluar. Ini bisa memakan waktu cukup lama, terutama saat dijalankan sebagai pengguna non-admin.

6. Jalankan citra Linux Anda di QEMU

Langkah ini yang akan Anda lakukan berulang kali untuk menjalankan VM setiap kali Anda membutuhkannya. Salin yang berikut ke runvm.bat :

@echo off

rem ==================================
rem Replace with your values
rem ==================================
set "QEMUDIR=%USERPROFILE%\Documents\Warez\qemu-2.8.0-win64"

rem ==================================
rem You can add a w suffix to this if 
rem you don't want a console
rem ==================================
set "QEMUBIN=qemu-system-x86_64.exe"

rem ==================================
rem Run the virtual machine
rem ==================================
start "QEMU" %QEMUDIR%\%QEMUBIN% -drive file=hda.img,index=0,media=disk,format=raw -m 2G -L Bios -usbdevice mouse -usbdevice keyboard -boot menu=on -rtc base=localtime,clock=host -parallel none -serial none -name centos -no-acpi -no-hpet -no-reboot -device e1000,netdev=user.0 -netdev user,id=user.0,hostfwd=tcp::2222-:22

Saya menambahkan portforward lokal:jika Anda ssh/putty ke localhost:2222, Anda akan mencapai daemon SSH VM Anda. Berhati-hatilah dengan firewalld itu atau iptables mungkin memblokir lalu lintas, bergantung pada cara Anda memasang Linux.

Manual Qemu akan menjadi tempat yang baik untuk memulai. Ini akan membantu Anda mengetahui apa yang harus Anda lakukan selanjutnya, yaitu memberi tahu qemu apa yang harus dilakukan, dan bagaimana tepatnya melakukannya.